build.bat

Plugins and extensions for Extensible components, usage examples, links to applications using Extensible, etc.

build.bat

Postby devil1591 » Tue Dec 07, 2010 7:13 am

Hello Brian,

I've created a build.bat for windows, I know this is on your roadmap.
Here is the code.

Code: Select all
@echo off
cls

:: Configuration
set VER=extensible-1.0-beta1
set EXTENSIBLE_ROOT=D:\Projects\Extensible
set EXTENSIBLE_OUTPUT=%EXTENSIBLE_ROOT%\deploy

:: Program start
echo.
IF NOT EXIST %EXTENSIBLE_ROOT%\NUL GOTO E_FOLDER_NOT_FOUND
IF "%1" == "-h" GOTO E_USAGE

:: Build it
java -jar JSBuilder2.jar --projectFile %EXTENSIBLE_ROOT%\extensible.jsb2 --homeDir %EXTENSIBLE_OUTPUT%

:: Copy the deploy files back into dev so that the samples get the latest code
echo Updating dev...
xcopy "%EXTENSIBLE_OUTPUT%\%VER%\extensible-all.js" "%EXTENSIBLE_ROOT%" /H /Y
xcopy "%EXTENSIBLE_OUTPUT%\%VER%\extensible-all-debug.js" "%EXTENSIBLE_ROOT%" /H /Y
xcopy "%EXTENSIBLE_OUTPUT%\%VER%\resources\css\extensible-all.css" "%EXTENSIBLE_ROOT%\resources\css" /H /Y

:: Copy textile files to output
xcopy "%EXTENSIBLE_ROOT%\*.textile" "%EXTENSIBLE_OUTPUT%\%VER%\" /H /Y

IF "%1" == "-d" (
   echo Generating docs...
   java -jar ext-doc.jar -p extensible.xml -o %EXTENSIBLE_OUTPUT%\%VER%\docs -t template\ext\template.xml
)

echo All done!
goto EOF

:E_FOLDER_NOT_FOUND
echo The folder %EXTENSIBLE_ROOT% doesn't exist!
echo Please update build.bat with the correct path for EXTENSIBLE_ROOT
goto EOF

:E_USAGE
echo usage: build.bat [-d]
echo.
echo        -d: Include updated docs in the output

:EOF
echo.
ExtJS: 3.3.1 - Ext.ensible: 1.0.1 - Windows XP SP3 - Firefox 6.0.1
User avatar
devil1591
 
Posts: 36
Joined: Thu Oct 07, 2010 2:34 am
Location: Paris, France

Re: build.bat

Postby brian.moeskau » Mon Dec 13, 2010 11:50 am

Added to Git and updated the README. I had actually started on this myself but not finished it, so this helped a lot! Thanks.
Personal Blog: Extraneous / Twitter: @bmoeskau / Meetup: Austin Bleeding Edge Web
User avatar
brian.moeskau
Site Admin
Site Admin
 
Posts: 1344
Joined: Sat Sep 18, 2010 5:00 pm
Location: Austin, Texas


Return to Plugins, Examples & Extras

Who is online

Users browsing this forum: No registered users and 1 guest

cron